mirror of
https://github.com/philmmanjaro/alma.git
synced 2025-07-23 21:49:28 +02:00
37 lines
976 B
Bash
37 lines
976 B
Bash
# Maintainer: James McMurray <jamesmcm03@gmail.com>
|
|
# Contributor: Roey Darwish Dror <roey.ghost@gmail.com>
|
|
|
|
_pkgname="alma"
|
|
pkgname="alma-git"
|
|
pkgver=r108.3ca2e01
|
|
pkgrel=1
|
|
pkgdesc='Create Arch Linux based live USB'
|
|
arch=('x86_64')
|
|
url='https://github.com/philmmanjaro/alma'
|
|
license=('GPL3')
|
|
makedepends=('git' 'rust')
|
|
depends=('gptfdisk' 'parted' 'arch-install-scripts' 'dosfstools' 'coreutils' 'util-linux')
|
|
optdepends=('cryptsetup: for root filesystem encryption')
|
|
source=("git+https://github.com/philmmanjaro/${_pkgname}")
|
|
provides=('alma')
|
|
conflicts=('alma')
|
|
sha256sums=('SKIP')
|
|
|
|
pkgver() {
|
|
cd "${srcdir}/${_pkgname}"
|
|
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
|
|
}
|
|
|
|
build() {
|
|
cd "${srcdir}/${_pkgname}"
|
|
|
|
cargo build --release
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/${_pkgname}"
|
|
|
|
install -Dm755 target/release/${_pkgname} "${pkgdir}/usr/bin/${_pkgname}"
|
|
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
|
|
}
|